趣味教程:从女娲造人谈类、属性、方法及实例(2)
作者 佚名技术
来源 服务器技术
浏览
发布时间 2012-07-10
|
趣味教程:从女娲造人谈类、属性、方法及实例(2) 前言:在上篇中谈到女娲不甘寂寞，用泥土捏出了一个个会走动、具灵气的"人"，可是忘了交代一下"人" 的才能到底如何。在女娲开始大批量造人之前先给我们"人"个舞台，让他展现一下自己的才能吧！
--女娲造人.fla 开始--
| var 女娲:神=new 神("善","女娲","人身蛇尾","女");
trace(女娲.姓名+"是一位"+女娲.形体+女娲.性别+神.类别);
trace("她是"+女娲.善恶+神.类别);
trace("一天,她觉得");
女娲.寂寞();
trace("于是,她开始");
var 原始人:Object=女娲.创造("人");
//将创造出来的"人"赋值给变量''原始人'',以后就可以通过''原始人''访问他的属性与方法。
trace("----原始人开始展示自己的才能----");
trace("原始人是"+原始人.性别+原始人.类别);
trace("原始人的形体是"+原始人.形体);
trace("原始人会直立行走，现在他(她)在:");
原始人.直立行走();
trace("原始人能言会语，现在他(她)在:");
原始人.能言会语();
trace("原始人聪明灵巧，现在他(她)在:");
原始人.聪明灵巧() |
|
?
--女娲造人.fla 结束--
我们人的表现如何呢?现在测试一下:
--女娲造人.fla 测试开始--
伟大的神女娲是一位神奇的人身蛇尾女神
她是善神
一天,她觉得
"我好孤单啊，有个人陪陪我多好啊!"
于是,她开始
捏泥人...
一个泥人制作完毕!
吹口气...
泥人学会直立行走!
泥人学会语言!
泥人学会思考!
泥人性别是女!
泥人具备了灵魂!
一个人诞生了!
----原始人开始展示自己的才能----
原始人是女人
原始人的形体是人身人腿
原始人会直立行走，现在他(她)在:
打架摔交中...
原始人能言会语，现在他(她)在:
谈情说爱中...
原始人聪明灵巧，现在他(她)在:
坑蒙拐骗中...
--女娲造人.fla 测试结束--
看到测试结果，你的感受如何呢？这个这个嘛，还是''人之初，性本恶''吧？
废话少说，言归正传。话说女娲想让人们遍布广阔的大地，但象她这样一个一个捏制下去希望实在渺茫啊。而且我们也看到了，其实每个泥人的样子虽然各不相同，但灵魂却是相似的，都是女娲的一口气使然。如果每个人都需要从女娲那里来那么一口，不把女娲累死也得元气大伤吧!那么女娲该怎么办呢?传说里说女娲拿了根绳子甩啊甩的就造出了很多人，看来得从这根''绳''子着手了.
这根绳子如此不一般，我认为是女娲把造人的模版倾注其中的结果。传说里又说，女娲是''按照自己的行貌''造的人，可以肯定''人''一定是从神那里继承了不少的特性吧。
--人.as开始--
| class 人 extends 神 {
//extends:定义类与类之间继承关系的关键字,子类对父类的特性可以保留或扬弃。
static var 类别:String = "人";
static var 所属:Object = 神;
//看到没，人是归神所管的哦
static var 气:Array = ["阳", "阴"];
static function 设置性别():String {
var 随即气 = 人.气[Math.floor(Math.random()*2)];
if (随即气 == "阴") {
return "女";
} else if (随即气 == "阳") {
return "男";
}
}
public function set 形体(x:String):Void {
//毕竟人和神的形体有很大的不同，神的形体千变万化，人的形体却大体是相似的，所以子类重写了父类的 ''set 形体()''方法.
//x:形体的状况,如是怎样的身材等等
if (x == undefined) {
x = "平常";
}
//如果没有提供''形体''的详细描述,那么用默认值''平常''。
__形体 = x+"人体";
}
public function get 形体():String{
//这个方法有点奇怪,本来应该直接继承就可以了，但却不得不再写一遍,原因不明。或者set 与 get 要配对出现?
return __形体;
}
function 人(x) {
//人的诞生无法和神相比啦，重写构造函数
//x:形体
//与神相比，人的构造函数只有''形体''一项参数,因为人的善恶跟后来的成长过程有关，
//性别由自然规则来定，姓名是后来由别人给命名的...只有身体是与天俱来的
//善恶=undefined 这里写出来，是提醒大家善恶现在其实是undefined的
//姓名=undefined
形体 = x;
性别 = 人.设置性别();
//调用类方法来初始化性别
trace("人诞生了!");
}
//下面的是继承来的方法
public function 寂寞():Void {
//寂寞者，人神皆然。不过''人''对''神''的寂寞有所拓展
super.寂寞();
//super:指向父类对象的关键字,因为''人''与神的寂寞有相同的地方，所以这里先调用''神''的‘寂寞’方法。
trace("哪怕是陪我聊聊天也行哦!");
//神会把''寂寞''转化为''创造'',人却把''寂寞''转化为''有聊''~~
}
public function 创造(o:Object):Object {
//人是没有神那么伟大的创造力...重写''创造''方法
if (o == "火") {
var o = new Object();
o.名称 = "火";
o.烤 = function(oo:Object) {
trace(oo+"烤熟了!");
};
trace("发明钻木取火！");
return o;
}
//其他的创造能力...略
}
//public function 捏泥人()... 人和神的 ‘捏泥人’没啥区别，完全继承之
public function 吹口气(o:Object) {
//由私有方法成为公有方法
//唉,一般来说子类对父类的功能都是有所拓展或增强的,唯独由神到人有点特别呀，
//拓展的只是些皮毛无聊的小功能，象这‘吹口气’的大本领就没继承来!要是吹口气吹出银子来...
if (o == undefined) {
//如果无东西可吹
trace("哎,这觉睡得好长啊");
//等于是打个哈欠吧
} else if (o == " 蜡烛") {
trace("蜡烛灭了");
//吹吹蜡烛~
} else if (o == this) {
//this:表示对象自身的关键字。
//如果吹的对象是自己
trace("哪里哪里，我也是略懂一二...你有什么要请教的?");
//唉，我也难免吹吹自己的~
} else if (o instanceof 人.所属) {
//如果吹的对象是人类的主宰的话
trace("爹亲娘亲没有"+o.姓名+"亲!");
//得 ,这又是在拍了~
}
}
//下面是人自己的方法
public function 直立行走() {
trace("打架摔交中...");
}
public function 能言会语() {
trace("谈情说爱中...");
}
public function 聪明灵巧() {
trace("坑蒙拐骗中...");
}
} |
|
|
凌众科技专业提供服务器租用、服务器托管、企业邮局、虚拟主机等服务，公司网站：http://www.lingzhong.cn
为了给广大客户了解更多的技术信息，本技术文章收集来源于网络,凌众科技尊重文章作者的版权，如果有涉及你的版权有必要删除你的文章，请和我们联系。以上信息与文章正文是不可分割的一部分,如果您要转载本文章,请保留以上信息，谢谢!
|
